***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jun 04, 2021                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.SUBCKT  PJA3449-AU  D  G  S
rg     G    1t    1
m1     2    1     3    3    dmos    L=1u   W=1u
.model dmos pmos (
+  vto = -1.9		   kp = 5.6		tnom = 25
+level = 3		gamma = 1.45
+   rb = 1.5e-3		)
cgs	1t	3	1.24n
rd	D	4	3.5e-2			  tc = 7e-3
dds	4	3	dds
.model     dds    d(
+bv = 44		ibv = 0.25e-6		tbv1 = 0.74e-3
+ m = 0.8856		cjo = 393p		  vj = 0.6487
+is = 7.089e-11		  n = 1.413		  rs = 1.0e-3	 	trs1 = 5e-4)
evgs 3 2t  table { V(S, 1t) }
+ ((0   , 0   )
+  (1.00, 1.00)
+  (1.50, 1.40)
+  (2.00, 1.60)
+  (2.50, 2.13)
+  (2.75, 2.37)
+  (3.00, 2.70)
+  (3.50, 3.50)
+  (3.75, 3.85)
+  (4.00, 4.06)
+  (4.25, 4.24)
+  (4.50, 4.31)
+  (4.75, 4.36)
+  (5.00, 4.40)
+  (6.00, 4.55)
+  (8.00, 4.79)
+  (10.0, 5.00))
dbody   D    3    dbody
evgst 1 2t value = {6e-4*limit(v(2t,3),-5,0)*limit((temp-25),-80,125)}
.model   dbody    d(
+is = 7.089e-11		 n = 1.413		rs = 1.0e-3		 trs1 = 5e-4
+tt = 100n		vj = 0.8		eg = 1.001)
ra      4    2    3.8e-2  tc=1e-2
rs      3    5    2.2e-2
ls      5    S    0.0001n
m2     1t    8    6    6   inter
e2      8    6    4    1t   2
.model   inter    pmos(vto=0  kp=10   level=1)
cgdmax  7    4    431p
rcgd    7    4    10meg
dgd     4    6    dgd
rdgd    4    6    10meg
.model     dgd    d(m=0.3  cjo=68p   vj=0.4)
m3      7    9    1t    1t   inter
e3      9    1t    4    1t   -2
.ends
*$
